added the Planet Cute images to the (new) 2htdp/planetcute library

collects/2htdp/planetcute.rkt

@@ -0,0 +1,14 @@
+#lang racket/base
+(require 2htdp/image
+         (for-syntax "private/planetcute-image-list.rkt")
+         (for-syntax racket/base))
+
+(define-syntax (definitions stx)
+  #`(begin
+      #,@(for/list ([img (in-list images)])
+           (define req (string->symbol (format "2htdp/planetcute/~a" (name->filename img))))
+           #`(begin
+               (provide #,img)
+               (define #,img (bitmap #,req))))))
+
+(definitions)

collects/2htdp/private/planetcute-image-list.rkt

@@ -0,0 +1,67 @@
+#lang racket/base
+(provide images name->filename)
+
+(define (name->filename img)
+  (define-values (_ new-chars)
+    (for/fold ([cap-next? #t]
+               [chars '()])
+      ([c (in-string (format "~a" img))])
+      (values (equal? #\- c)
+              (cons (cond
+                      [(equal? c #\-) #\space]
+                      [cap-next? (char-upcase c)]
+                      [else c])
+                    chars))))
+  (format "~a.png" (apply string (reverse new-chars))))
+
+(define images
+  '(brown-block
+    character-boy
+    character-cat-girl
+    character-horn-girl
+    character-pink-girl
+    character-princess-girl
+    chest-closed
+    chest-lid
+    chest-open
+    dirt-block
+    door-tall-closed
+    door-tall-open
+    enemy-bug
+    gem-blue
+    gem-green
+    gem-orange
+    grass-block
+    heart
+    key
+    plain-block
+    ramp-north
+    ramp-south
+    ramp-west
+    roof-east
+    roof-north-east
+    roof-north-west
+    roof-north
+    roof-south-east
+    roof-south-west
+    roof-south
+    roof-west
+    shadow-east
+    shadow-north-east
+    shadow-north-west
+    shadow-north
+    shadow-side-west
+    shadow-south-east
+    shadow-south-west
+    shadow-south
+    shadow-west
+    stone-block-tall
+    stone-block
+    tree-short
+    tree-tall
+    tree-ugly
+    wall-block-tall
+    wall-block
+    water-block
+    window-tall
+    wood-block))

collects/teachpack/2htdp/scribblings/2htdp.scrbl

@@ -11,3 +11,4 @@
 @include-section["image.scrbl"]
 @include-section["universe.scrbl"]
 @include-section["port.scrbl"]
+@include-section["planetcute.scrbl"]

collects/teachpack/2htdp/scribblings/image.scrbl

@@ -1224,6 +1224,8 @@ are represented as bitmaps, i.e., an array of colors (that can be quite large in
 This means that scaling and rotating them loses fidelity in the image and is significantly
 more expensive than with the other shapes.
 
+See also the @racketmodname[2htdp/planetcute] library.
+
 @defform/subs[(bitmap bitmap-spec)
               ([bitmap-spec rel-string
                             id])]{

collects/teachpack/2htdp/scribblings/planetcute.scrbl

@@ -0,0 +1,60 @@
+#lang scribble/doc
+
+@(require "shared.rkt" 
+          "port.rkt"
+          scribble/manual
+          scribble/eval
+          (for-syntax racket/base)
+          2htdp/image
+          (for-label 2htdp/image
+                     2htdp/planetcute))
+
+@; -----------------------------------------------------------------------------
+
+@title{Planet Cute Images}
+
+@defmodule[2htdp/planetcute]
+
+@(define pc-eval (make-base-eval))
+@(interaction-eval #:eval pc-eval (require 2htdp/image))
+@(interaction-eval #:eval pc-eval (require 2htdp/planetcute))
+
+The @racketmodname[2htdp/planetcute] library contains the 
+Planet Cute images:
+@url{http://www.lostgarden.com/2007/05/dancs-miraculously-flexible-game.html}.
+
+The images are designed to be overlaid with each other to build
+scenes for use in games. Here is an example image taken
+from the Planet Cute website.
+
+@racketblock+eval[#:eval 
+                  pc-eval
+                  (define (stack arg . args)
+                    (cond
+                      [(null? args) arg]
+                      [else (overlay/xy arg 0 40
+                                        (apply stack args))]))]
+@interaction[#:eval 
+             pc-eval
+             (scale
+              1
+              (beside/align
+               "bottom"
+               (stack wall-block-tall stone-block)
+               (stack character-cat-girl
+                      stone-block stone-block
+                      stone-block stone-block)
+               water-block
+               (stack grass-block dirt-block)
+               (stack grass-block dirt-block dirt-block)))]
+
+@(close-eval pc-eval)
+           
+@(require (for-syntax 2htdp/private/planetcute-image-list))
+@(define-syntax (defthings stx)
+   #`(begin
+       #,@(for/list ([img (in-list images)])
+            (define req (string->symbol (format "2htdp/planetcute/~a" (name->filename img))))
+            #`@defthing[#,img image?]{  @(bitmap #,req) })))
+
+@defthings[]